surfer/openssl-act-engine/configure.in

## @id $Id$

##       1         2         3         4         5         6         7         8
## 45678901234567890123456789012345678901234567890123456789012345678901234567890

# init
AC_INIT([README])
SRC_DIR=src
TST_DIR=
DOC_DIR=doc

m4_define(x_packagename, openssl-act-engine)
m4_define(x_major, 1)
m4_define(x_minor, 0)

PACKAGENAME=x_packagename
MAJOR=x_major
MINOR=x_minor

LEAST="ERROR-UNDEFINED-REVISION-to-be-built-in-subdirectory-of-svn-checkout"
for path in . .. ../..; do
  if svn info $path 2>&1 > /dev/null; then
    LEAST=$(LANG= svn info $path | sed -n 's/Revision: //p')
    break;
  fi
done

AM_INIT_AUTOMAKE($PACKAGENAME, $MAJOR.$MINOR.$LEAST, [marc@waeckerlin.org])

# files to create
AC_CONFIG_FILES(makefile src/makefile doc/makefile doc/doxyfile)

AC_SUBST(MAJOR)
AC_SUBST(MINOR)
AC_SUBST(LEAST)

README=README
AC_SUBST_FILE(README)

# libtool versioning
LIB_MAJOR=m4_eval(x_major+x_minor)
LIB_MINOR=$LEAST
LIB_LEAST=x_minor
LIB_VERSION="${LIB_MAJOR}:${LIB_MINOR}:${LIB_LEAST}"
AC_SUBST(LIB_VERSION)

# Get rid of that stupid -O2 -g options!
CXXFLAGS="${CXXFLAGS:-} -pthread"

# languages
AC_LANG(C++)

# programs
AC_PROG_CXX
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET
AC_PROG_LIBTOOL
AC_CHECK_PROG(have_doxygen, doxygen, yes, no)
AC_CHECK_PROG(have_dot, dot, yes, no)

case ${host} in
  (*linux*) case "${host}" in
      (*i386*) LDFLAGS+=" -L../../actlibrary/Ubuntu-9-i686/Release"
      ;;
      (*i686|x86_64*) LDFLAGS+=" -L../../actlibrary/OpenSUSE-11-x86_64/Release"
      ;;
      (*) AC_MSG_ERROR([Unknown Linux Host: $host])
      ;;
    esac
    AM_CONDITIONAL(WIN32, false)
    ;;
  (*mingw*) 
    LDFLAGS+=" -L../../actlibrary/mingw32-i586/Release"
    AM_CONDITIONAL(WIN32, true)
    ;;
  (i386-apple-darwin*) LDFLAGS+=" -L../../actlibrary/MacOSX-10.5-x86_64/Release"
    AM_CONDITIONAL(WIN32, false)
    ;;
  (*) AC_MSG_ERROR([Unknown Host: $host])
    ;;
esac

AC_ARG_ENABLE(pedantic,
  [AS_HELP_STRING([--enable-pedantic],
                  [enable all warnings and checks, abort on warnings])],
  [have_pedantic="$enableval"; test "$enableval" = "yes" &&  \
     AM_CXXFLAGS="${AM_CXXFLAGS:-} -pedantic-errors -Wall -W -Wfloat-equal -Wundef -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Wconversion -Wsign-compare -Wmissing-format-attribute -Wno-multichar -Wpacked -Wredundant-decls -Werror -Wshadow -Wcast-qual -Wno-ctor-dtor-privacy"])
dnl problem in libs: -Wshadow -Wcast-qual
dnl auto.hpp: -Wno-ctor-dtor-privacy (removed)
AM_CONDITIONAL(PEDANTIC, test "$enableval" = "yes")
AC_ARG_ENABLE(dot,
  [AS_HELP_STRING([--disable-dot],
                  [disable dot graphic tools for documentation])],
  [have_dot="$enableval"])
test "$enableval" = "yes" && HAVE_DOT="YES" || HAVE_DOT="NO";
AM_PATH_CPPUNIT([1.0.0], [have_cppunit="yes"], [have_cppunit="no"])

# export macros
SRCDIR=${srcdir}
AC_SUBST(SRCDIR)
AC_SUBST(SRC_DIR)
AC_SUBST(TST_DIR)
AC_SUBST(DOC_DIR)
AC_SUBST(HAVE_DOT)
AC_SUBST(THREADS)
AC_SUBST(PACKAGENAME)
AC_SUBST(AM_CXXFLAGS)
AC_SUBST(AM_CPPFLAGS)
AC_SUBST(LIBS)
AC_SUBST(QMAKE)
AC_SUBST(QMAKE_OPTIONS)

# create output
AC_OUTPUT

# infos and warnings
if test "$have_doxygen" = "no"; then
AC_MSG_WARN([Missing program doxygen!
  - you cannot rebuild the documentation with make doc
  - there are precompiled derived files in the distribution]); fi
if test "$have_dot" = "no"; then
AC_MSG_WARN([Missing program dot!
  - when you rebild documentation with make doc, there are no generated images
  - there are precompiled derived files in the distribution]); fi
if test "$have_cppunit" = "no"; then
AC_MSG_WARN([Missing cppunit development library!
  - you cannot check the library using "make check"
  - everything else works perfectly]); fi
if test "$have_pedantic" == "yes"; then
AC_MSG_NOTICE([Pedantic compile mode enabled!
  - all warnings for GNU g++ are enabled
  - all warnings result in an error
  - doxygen warnings are treated as error too]); fi
if test "$build_win" == "yes"; then
AC_MSG_NOTICE([Will cross-compile for windows
  Requires:
    - mingw32, mingw32-binutils, mingw32-runtime
      - i586-mingw32msvc-g++, i586-mingw32msvc-ar,
        i586-mingw32msvc-windres, i586-mingw32msvc-strip
    - Boost for MinGW in ~/.wine/drive_c/Programme/Boost-1.34.1]); fi