same qt configuration as in libpcscxx; refs #40

ax_cxx_compile_stdcxx_11.m4

@@ -0,0 +1,133 @@
+# ============================================================================
+#  http://www.gnu.org/software/autoconf-archive/ax_cxx_compile_stdcxx_11.html
+# ============================================================================
+#
+# SYNOPSIS
+#
+#   AX_CXX_COMPILE_STDCXX_11([ext|noext],[mandatory|optional])
+#
+# DESCRIPTION
+#
+#   Check for baseline language coverage in the compiler for the C++11
+#   standard; if necessary, add switches to CXXFLAGS to enable support.
+#
+#   The first argument, if specified, indicates whether you insist on an
+#   extended mode (e.g. -std=gnu++11) or a strict conformance mode (e.g.
+#   -std=c++11).  If neither is specified, you get whatever works, with
+#   preference for an extended mode.
+#
+#   The second argument, if specified 'mandatory' or if left unspecified,
+#   indicates that baseline C++11 support is required and that the macro
+#   should error out if no mode with that support is found.  If specified
+#   'optional', then configuration proceeds regardless, after defining
+#   HAVE_CXX11 if and only if a supporting mode is found.
+#
+# LICENSE
+#
+#   Copyright (c) 2008 Benjamin Kosnik <bkoz@redhat.com>
+#   Copyright (c) 2012 Zack Weinberg <zackw@panix.com>
+#   Copyright (c) 2013 Roy Stogner <roystgnr@ices.utexas.edu>
+#
+#   Copying and distribution of this file, with or without modification, are
+#   permitted in any medium without royalty provided the copyright notice
+#   and this notice are preserved. This file is offered as-is, without any
+#   warranty.
+
+#serial 3
+
+m4_define([_AX_CXX_COMPILE_STDCXX_11_testbody], [
+  template <typename T>
+    struct check
+    {
+      static_assert(sizeof(int) <= sizeof(T), "not big enough");
+    };
+
+    typedef check<check<bool>> right_angle_brackets;
+
+    int a;
+    decltype(a) b;
+
+    typedef check<int> check_type;
+    check_type c;
+    check_type&& cr = static_cast<check_type&&>(c);
+
+    auto d = a;
+])
+
+AC_DEFUN([AX_CXX_COMPILE_STDCXX_11], [dnl
+  m4_if([$1], [], [],
+        [$1], [ext], [],
+        [$1], [noext], [],
+        [m4_fatal([invalid argument `$1' to AX_CXX_COMPILE_STDCXX_11])])dnl
+  m4_if([$2], [], [ax_cxx_compile_cxx11_required=true],
+        [$2], [mandatory], [ax_cxx_compile_cxx11_required=true],
+        [$2], [optional], [ax_cxx_compile_cxx11_required=false],
+        [m4_fatal([invalid second argument `$2' to AX_CXX_COMPILE_STDCXX_11])])dnl
+  AC_LANG_PUSH([C++])dnl
+  ac_success=no
+  AC_CACHE_CHECK(whether $CXX supports C++11 features by default,
+  ax_cv_cxx_compile_cxx11,
+  [AC_COMPILE_IFELSE([AC_LANG_SOURCE([_AX_CXX_COMPILE_STDCXX_11_testbody])],
+    [ax_cv_cxx_compile_cxx11=yes],
+    [ax_cv_cxx_compile_cxx11=no])])
+  if test x$ax_cv_cxx_compile_cxx11 = xyes; then
+    ac_success=yes
+  fi
+
+  m4_if([$1], [noext], [], [dnl
+  if test x$ac_success = xno; then
+    for switch in -std=gnu++11 -std=gnu++0x; do
+      cachevar=AS_TR_SH([ax_cv_cxx_compile_cxx11_$switch])
+      AC_CACHE_CHECK(whether $CXX supports C++11 features with $switch,
+                     $cachevar,
+        [ac_save_CXXFLAGS="$CXXFLAGS"
+         CXXFLAGS="$CXXFLAGS $switch"
+         AC_COMPILE_IFELSE([AC_LANG_SOURCE([_AX_CXX_COMPILE_STDCXX_11_testbody])],
+          [eval $cachevar=yes],
+          [eval $cachevar=no])
+         CXXFLAGS="$ac_save_CXXFLAGS"])
+      if eval test x\$$cachevar = xyes; then
+        CXXFLAGS="$CXXFLAGS $switch"
+        ac_success=yes
+        break
+      fi
+    done
+  fi])
+
+  m4_if([$1], [ext], [], [dnl
+  if test x$ac_success = xno; then
+    for switch in -std=c++11 -std=c++0x; do
+      cachevar=AS_TR_SH([ax_cv_cxx_compile_cxx11_$switch])
+      AC_CACHE_CHECK(whether $CXX supports C++11 features with $switch,
+                     $cachevar,
+        [ac_save_CXXFLAGS="$CXXFLAGS"
+         CXXFLAGS="$CXXFLAGS $switch"
+         AC_COMPILE_IFELSE([AC_LANG_SOURCE([_AX_CXX_COMPILE_STDCXX_11_testbody])],
+          [eval $cachevar=yes],
+          [eval $cachevar=no])
+         CXXFLAGS="$ac_save_CXXFLAGS"])
+      if eval test x\$$cachevar = xyes; then
+        CXXFLAGS="$CXXFLAGS $switch"
+        ac_success=yes
+        break
+      fi
+    done
+  fi])
+  AC_LANG_POP([C++])
+  if test x$ax_cxx_compile_cxx11_required = xtrue; then
+    if test x$ac_success = xno; then
+      AC_MSG_ERROR([*** A compiler with support for C++11 language features is required.])
+    fi
+  else
+    if test x$ac_success = xno; then
+      HAVE_CXX11=0
+      AC_MSG_NOTICE([No compiler with C++11 support was found])
+    else
+      HAVE_CXX11=1
+      AC_DEFINE(HAVE_CXX11,1,
+                [define if the compiler supports basic C++11 syntax])
+    fi
+
+    AC_SUBST(HAVE_CXX11)
+  fi
+])

configure.in

@@ -1,4 +1,5 @@
 # $Id$
+m4_include(ax_cxx_compile_stdcxx_11.m4)
 AC_ALIAS([AC_DEFINE_DIR], [AX_DEFINE_DIR])
 AC_DEFUN([AX_DEFINE_DIR], [
   prefix_NONE=
@@ -91,6 +92,31 @@ AC_CHECK_PROG(have_doxygen, doxygen, yes, no)
 AC_CHECK_PROG(have_dot, dot, yes, no)
 PKG_PROG_PKG_CONFIG
 
+# libraries
+PKG_CHECK_MODULES([QT], [Qt5Core Qt5Gui Qt5Widgets QtNetwork],
+   [AC_DEFINE([HAVE_QT])
+    UIC=${UIC:-$(pkg-config --variable=uic_location Qt5Core)}
+    MOC=${MOC:-$(pkg-config --variable=moc_location Qt5Core)}
+    RCC=${RCC:-$(pkg-config --variable=rcc_location Qt5Core)}
+    LUPDATE=${LUPDATE:-$(pkg-config --variable=lupdate_location Qt5Core)}
+    LRELEASE=${LRELEASE:-$(pkg-config --variable=lrelease_location Qt5Core)}
+    have_qt=1],
+   [PKG_CHECK_MODULES([QT], [QtCore QtGui QtNetwork],
+       [AC_DEFINE([HAVE_QT])
+        UIC=${UIC:-$(pkg-config --variable=uic_location QtCore)}
+        MOC=${MOC:-$(pkg-config --variable=moc_location QtCore)}
+        RCC=${RCC:-$(pkg-config --variable=rcc_location QtCore)}
+        LUPDATE=${LUPDATE:-$(pkg-config --variable=lupdate_location QtCore)}
+        LRELEASE=${LRELEASE:-$(pkg-config --variable=lrelease_location QtCore)}
+        have_qt=1],
+       [have_qt=0])])
+AM_CONDITIONAL(HAVE_QT, test "$have_qt" = "1")
+AC_SUBST(UIC)
+AC_SUBST(MOC)
+AC_SUBST(RCC)
+AC_SUBST(LUPDATE)
+AC_SUBST(LRELEASE)
+
 AC_ARG_ENABLE(pedantic,
   [AS_HELP_STRING([--enable-pedantic],
                   [enable all warnings and checks, abort on warnings])],
@@ -115,6 +141,13 @@ esac
 AM_CONDITIONAL(MINGW32, test "$MINGW32" = "yes")
 AM_CONDITIONAL(MAC, test "$MAC" = "yes")
 
+# author for signing packages
+if test -z "$PACKAGERID"; then
+   PACKAGERID="Marc Wäckerlin (http://marc.waeckerlin.org) <marc@waeckerlin.org>"
+fi
+AC_ARG_VAR(PACKAGERID, [Signature identification of the package author.])
+BUILDDATE=$(date --rfc-2822)
+
 # export macros
 SRCDIR=${srcdir}
 AC_SUBST(SRCDIR)
@@ -127,88 +160,6 @@ AC_SUBST(PACKAGENAME)
 AC_SUBST(AM_CXXFLAGS)
 AC_SUBST(AM_CPPFLAGS)
 AC_SUBST(LIBS)
-# Qt Environment
-AC_MSG_CHECKING(QT directory)
-QTDIR="no"
-AC_ARG_WITH([qt-dir],
-             AC_HELP_STRING([--with-qt-dir=/path/to/Qt],
-                            [to specify the path to the Qt directory.]),
-             [QTPATHS="$withval"],
-             [QTPATHS="/usr/include /usr/local/include /opt/include /opt/local/include /usr/include/qt4 /usr/local/include/qt4 /opt/include/qt4 /opt/local/include/qt4 /opt/local/libexec/qt4-mac/include"])
-for x in $QTPATHS; do
-    if test -d $x/QtCore ; then
-       QTINCDIR=$x
-       QTDIR=${x%/include*}
-       if test -d $QTDIR/lib; then
-         QTLIBDIR=$QTDIR/lib
-         break
-       fi
-    fi
-done
-AC_MSG_RESULT($QTDIR)
-AM_CONDITIONAL(USE_QT, test -n "$QTLIBDIR")
-if test -z "$QTLIBDIR"; then
-   AC_MSG_ERROR(Could not locate QT 4)
-  case $host in
-    *darwin*)
-      LDFLAGS+=" -lproxy"
-      ;;
-    *mingw*|*win*)
-      LDFLAGS+=" -lwinhttp"
-      ;;
-    *)
-      LDFLAGS+=" -lproxy"
-      ;;
-  esac
-else
-  # by now, Linux/Unix always uses libproxy
-  case $host in
-    *darwin*)
-      LDFLAGS+=" -L$QTLIBDIR -lQtCore -lQtNetwork -lQtGui"
-      ;;
-    *mingw*|*win*)
-      LDFLAGS+=" -L$QTLIBDIR -lQtCore4 -lQtNetwork4 -lQtGui4"
-      ;;
-    *)
-      LDFLAGS+=" -L$QTLIBDIR -lQtCore -lQtNetwork -lQtGui"
-      LDFLAGS+=" -lproxy"
-      ;;
-  esac
-  CPPFLAGS+=" -DUNICODE -DQT_NO_DEBUG"
-  CPPFLAGS+=" -DQT_GUI_LIB -DQT_NETWORK_LIB -DQT_WEBKIT_LIB -DQT_CORE_LIB"
-  CPPFLAGS+=" -I$QTINCDIR"
-  AC_ARG_WITH([moc],
-             AC_HELP_STRING([--with-moc=/path/to/moc],
-                            [to specify the path to qt moc.]),
-             [MOC="$withval"
-              RCC="$(dirname $withval)/rcc"
-              UIC="$(dirname $withval)/uic"
-              LRELEASE="$(dirname $withval)/lrelease"
-              LUPDATE="$(dirname $withval)/lupdate"],
-             [MOC="${QTDIR}/bin/moc"
-              RCC="${QTDIR}/bin/rcc"
-              UIC="${QTDIR}/bin/uic"
-              LRELEASE="${QTDIR}/bin/lrelease"
-              LUPDATE="${QTDIR}/bin/lupdate"])
-  AC_CHECK_PROGS([MOC], ["$MOC" moc moc-qt4 moc-mac])
-  test -n "$MOC" || AC_MSG_ERROR([moc for Qt not found!])
-  AC_SUBST(MOC)
-  AC_CHECK_PROGS([RCC], ["$RCC" rcc rcc-qt4 rcc-mac])
-  test -n "$RCC" || AC_MSG_ERROR([rcc for Qt not found!])
-  AC_SUBST(RCC)
-  AC_CHECK_PROGS([UIC], ["$UIC" uic uic-qt4 uic-mac])
-  test -n "$UIC" || AC_MSG_ERROR([uic for Qt not found!])
-  AC_SUBST(UIC)
-  AC_CHECK_PROGS([LRELEASE], ["$LRELEASE" lrelease lrelease-qt4 lrelease-mac])
-  test -n "$LRELEASE" || AC_MSG_ERROR([lrelease for Qt not found!])
-  AC_SUBST(LRELEASE)
-  AC_CHECK_PROGS([LUPDATE], ["$LUPDATE" lupdate lupdate-qt4 lupdate-mac])
-  test -n "$LUPDATE" || AC_MSG_ERROR([lupdate for Qt not found!])
-  AC_SUBST(LUPDATE)
-  AC_ARG_VAR(LUPDATE_ARGS, [arguments for qt lupdate command, e.g. -no-obsolete])
-fi
-DISTCHECK_CONFIGURE_FLAGS="$(env)"
-AC_SUBST(DISTCHECK_CONFIGURE_FLAGS)
 
 # create output
 AC_OUTPUT

examples/makefile.am

@@ -8,7 +8,7 @@ AM_LDFLAGS = -L${top_builddir}/src/.libs
 LDADD = -lproxyface
 
 noinst_PROGRAMS = getproxylist
-if USE_QT
+if QT
 noinst_PROGRAMS += simplegui
 simplegui_SOURCES = simplegui.cxx
 endif

src/makefile.am

@@ -5,7 +5,7 @@
 ##       1         2         3         4         5         6         7         8
 ## 45678901234567890123456789012345678901234567890123456789012345678901234567890
 
-if USE_QT
+if QT
 UISOURCES  = proxyface/proxy.ui proxyface/proxyauth.ui
 RESOURCES  = proxyface/resources.cxx
 MOCHEADER  = proxyface/proxy.hxx proxyface/autoproxy.hxx proxyface/proxyauth.hxx