# init
AC_INIT([README])
PACKAGENAME=swisssurfer
SRC_DIR=src
TST_DIR=
DOC_DIR=doc

m4_define(x_major, 1)
m4_define(x_minor, 0)
m4_define(x_least, 0)
AM_INIT_AUTOMAKE(@PACKAGENAME@, @MAJOR@.@MINOR@.@LEAST@, [marc@waeckerlin.org])

# files to create
AC_CONFIG_FILES(makefile
                src/makefile src/qmake.pro src/languages.qrc
                doc/doxyfile doc/makefile)

# copy M4 to shell
MAJOR=x_major
MINOR=x_minor
LEAST=x_least
AC_SUBST(MAJOR)
AC_SUBST(MINOR)
AC_SUBST(LEAST)

# libtool versioning
LIB_MAJOR=m4_eval(x_major+x_minor)
LIB_MINOR=x_least
LIB_LEAST=x_minor
LIB_VERSION="${LIB_MAJOR}:${LIB_MINOR}:${LIB_LEAST}"
AC_SUBST(LIB_VERSION)

# home
AC_SUBST(HOME)

# macros
README=README
AC_SUBST_FILE(README)
CHANGE_LOG=ChangeLog
AC_SUBST_FILE(CHANGE_LOG)

# Get rid of that stupid -O2 -g opions!
CXXFLAGS="${CXXFLAGS:-}"

# languages
AC_LANG(C++)

# programs
AC_PROG_CXX
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET
AC_PROG_LIBTOOL
AC_CHECK_PROG(have_doxygen, doxygen, yes, no)
AC_CHECK_PROG(have_dot, dot, yes, no)

AC_ARG_ENABLE(pedantic,
  [AS_HELP_STRING([--enable-pedantic],
                  [enable all warnings and checks, abort on warnings])],
  [have_pedantic="$enableval"; test "$enableval" = "yes" &&  \
     AM_CXXFLAGS="${AM_CXXFLAGS:-} -pedantic-errors -Wall -W -Wfloat-equal -Wundef -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Wconversion -Wsign-compare -Wmissing-format-attribute -Wno-multichar -Wpacked -Wredundant-decls -Werror -Wshadow -Wcast-qual -Wno-ctor-dtor-privacy"])
dnl problem in libs: -Wshadow -Wcast-qual
dnl auto.hpp: -Wno-ctor-dtor-privacy (removed)
AM_CONDITIONAL(PEDANTIC, test "$enableval" = "yes")
AC_ARG_ENABLE(dot,
  [AS_HELP_STRING([--disable-dot],
                  [disable dot graphic tools for documentation])],
  [have_dot="$enableval"])
test "$enableval" = "yes" && HAVE_DOT="YES" || HAVE_DOT="NO";
AM_PATH_CPPUNIT([1.0.0], [have_cppunit="yes"], [have_cppunit="no"])

# Special Options
AC_CHECK_PROGS([QMAKE], [qmake-qt4 qmake-mac qmake])
test -n "$QMAKE" || AC_MSG_ERROR([qmake for Qt 4 not found!])
AC_MSG_NOTICE([QMAKE IS: $QMAKE])
AC_SUBST(QMAKE)
AC_CHECK_PROGS([LRELEASE], [lrelease-qt4 lrelease-mac lrelease])
test -n "$LRELEASE" || AC_MSG_ERROR([lrelease for Qt 4 not found!])
AC_SUBST(LRELEASE)
AC_CHECK_PROGS([LUPDATE], [lupdate-qt4 lupdate-mac lupdate])
test -n "$LUPDATE" || AC_MSG_ERROR([lupdate for Qt 4 not found!])
AC_SUBST(LUPDATE)
QMAKE_OPTIONS=
AC_ARG_ENABLE(static-plugins,
  [AS_HELP_STRING([--enable-static-plugins],
                  [links the image plugins statically])],
  [static_plugins="$enableval"], [static_plugins="no"])
#AM_CONDITIONAL(STATIC_PLUGINS, test "$static_plugins" = "yes")
if test "$static_plugins" = "yes"; then
  CXXFLAGS+=" -DPLUGINS=static"
  STATIC_QTPLUGINS="qgif qjpeg qmng"
  STATIC_QCONFIG="static"
else
  CXXFLAGS+=" -DPLUGINS=dynamic"
  STATIC_QTPLUGINS=
  STATIC_QCONFIG=
fi
AC_ARG_ENABLE(win,
  [AS_HELP_STRING([--enable-win],
                  [on linux, also builds windows version using mingw])],
  [build_win="$enableval"], [build_win="no"])
AM_CONDITIONAL(BUILD_WIN, test "$build_win" = "yes")
AC_ARG_ENABLE(32bit-linux,
  [AS_HELP_STRING([--enable-32bit-linux],
                  [build for 32bit linux instead of plattform specific])],
  [build_lin32="$enableval"], [build_lin32="no"])
AM_CONDITIONAL(BUILD_LIN32, test "$build_lin32" = "yes")

# Environment Variables
AC_ARG_VAR(LUPDATE_ARGS, [arguments for qt lupdate command, e.g. -no-obsolete])

# Enviropnment Variables
AC_ARG_VAR(EDITION, [name of the edition, e.g. comol])
AC_ARG_VAR(EDITION_USERFRIENDLY, [userfriendly name of the edition, e.g. CoMoL])
AC_ARG_VAR(BUILDVERSION, [version of this build, e.g. v1.0])
AC_ARG_VAR(BUILD, [build number of this build, e.g. 213])

# export macros
SRCDIR=${srcdir}
AC_SUBST(SRCDIR)
AC_SUBST(SRC_DIR)
AC_SUBST(TST_DIR)
AC_SUBST(DOC_DIR)
AC_SUBST(HAVE_DOT)
AC_SUBST(THREADS)
AC_SUBST(PACKAGENAME)
AC_SUBST(AM_CXXFLAGS)
AC_SUBST(AM_CPPFLAGS)
AC_SUBST(LIBS)
AC_SUBST(QMAKE)
AC_SUBST(QMAKE_OPTIONS)
AC_SUBST(STATIC_QTPLUGINS)
AC_SUBST(STATIC_QCONFIG)

AC_CHECK_HEADER(xml-cxx/xml.hxx, [found="yes"], [found="no"])
if test "$found" == "no"; then
  AC_MSG_CHECKING([looking for xml-cxx headers])
  for file in /usr/include /usr/local/include /opt/include \
              /opt/local/include; do
    if test -d ${file}/xml-cxx; then
      CPPFLAGS+=" -I$file"
      LDFLAGS+=" -L$(echo $file | sed 's#/include#/lib#g')"
      found=$file
      break;
    fi
  done
  AC_MSG_RESULT([$found])
fi
if test "$found" == "no"; then
  AC_MSG_ERROR([libxml-cxx not found])
fi

# create output
AC_OUTPUT
# infos and warnings
AC_MSG_NOTICE([Build Information from Environment:
  - EDITION=$EDITION
  - EDITION_USERFRIENDLY=$EDITION_USERFRIENDLY
  - BUILDVERSION=$BUILDVERSION
  - BUILD=$BUILD
])
if test "$have_doxygen" = "no"; then
AC_MSG_WARN([Missing program doxygen!
  - you cannot rebuild the documentation with make doc
  - there are precompiled derived files in the distribution]); fi
if test "$have_dot" = "no"; then
AC_MSG_WARN([Missing program dot!
  - when you rebild documentation with make doc, there are no generated images
  - there are precompiled derived files in the distribution]); fi
if test "$have_cppunit" = "no"; then
AC_MSG_WARN([Missing cppunit development library!
  - you cannot check the library using "make check"
  - everything else works perfectly]); fi
if test "$have_pedantic" == "yes"; then
AC_MSG_NOTICE([Pedantic compile mode enabled!
  - all warnings for GNU g++ are enabled
  - all warnings result in an error
  - doxygen warnings are treated as error too]); fi
if test "$build_win" == "yes"; then
AC_MSG_NOTICE([Will cross-compile for windows
  Requires:
    - mingw32, mingw32-binutils, mingw32-runtime
      - i586-mingw32msvc-g++, i586-mingw32msvc-ar,
        i586-mingw32msvc-windres, i586-mingw32msvc-strip
    - Boost for MinGW in ~/.wine/drive_c/Programme/Boost-1.34.1
    - Qt for MinGW in ~/.wine/drive_c/Qt/4.4.3]); fi