QT += gui webkit network
CONFIG += designer plugin
QMAKE_LIBS += -lproxyface -lpcscxx -lssl -lcrypto
QMAKE_CXXFLAGS += -Wno-parentheses -Wno-unused-parameter
#-std=c++0x
QMAKE_INCDIR += @top_srcdir@/src
QMAKE_INCDIR += .
QMAKE_LIBDIR += @top_builddir@/src/qbrowserlib
QMAKE_LIBDIR += @top_builddir@/src/qbrowserlib/release
QMAKE_LIBS += -lqbrowserlib

unix {
  !macx {
    CONFIG += debug
    QMAKE_INCDIR += /usr/include/PCSC
    QMAKE_INCDIR += /usr/local/include/PCSC
    QMAKE_LIBS += -lpcsclite -lproxy
  }
}
macx {
  QMAKE_INCDIR += /opt/local/include
  QMAKE_LIBDIR += /opt/local/lib
  QMAKE_LFLAGS += -F/System/Library/Frameworks/PCSC.framework
  LIBS += -framework PCSC
  QMAKE_INCDIR += /System/Library/Frameworks/PCSC.framework/Headers
  QMAKE_INFO_PLIST = Info.plist
  CONFIG += x86
}
win32 {
  QMAKE_LIBS += -lwinhttp -lgdi32 -lws2_32
  QMAKE_LIBS += /opt/local/i586-mingw32msvc/lib/winscard.a
  QMAKE_LIBDIR += /opt/local/i586-mingw32msvc/lib
  CONFIG += dll
}

FORMS = 

RESOURCES = resources.qrc

TEMPLATE = lib

qbrowserlib-swisswebview {
  SOURCES = webviewwidgetifc.cxx
  HEADERS = webviewwidgetifc.hxx
  TARGET = qbrowserlib-swisswebview
}
qbrowserlib-buttonlineedit {
  SOURCES = buttonlineeditwidgetifc.cxx
  HEADERS = buttonlineeditwidgetifc.hxx
  TARGET = qbrowserlib-buttonlineedit
}

CODECFORSRC = UTF-8
CODECFORTR = UTF-8

DEFINES += VERSION=\'\"@VERSION@\"\' BUILDDATE=\'\"@BUILDDATE@\"\'

## DEBUG
# QMAKE_CXXFLAGS += -include iostream -D\"CRYPTOKI_LOG(X)=std::clog<<\\\"CRYPTOKI_\\\"<<X<<\\\"_@_\\\"<<__PRETTY_FUNCTION__<<std::endl\" -D\"PCSC_LOG(X)=std::clog<<\\\"PCSC_\\\"<<X<<\\\"_@_\\\"<<__PRETTY_FUNCTION__<<std::endl\" -D\"OPENSSL_LOG(X)=std::clog<<\\\"OPENSSL_\\\"<<X<<\\\"_@_\\\"<<__PRETTY_FUNCTION__<<std::endl'" @CPPFLAGS@ @CXXFLAGS@