QT += webkit network gui
CONFIG += no_keywords
QMAKE_LIBS += -lproxyface -lcryptoki++ -lssl -lcrypto

unix {
  !macx {
    CONFIG += debug
    QMAKE_INCDIR += /usr/include/PCSC
    QMAKE_INCDIR += /usr/local/include/PCSC
    QMAKE_LIBS += -lpcsclite
  }
}
macx {
  QMAKE_INCDIR += /opt/local/include
  QMAKE_LIBDIR += /opt/local/lib
  QMAKE_LFLAGS += -F/System/Library/Frameworks/PCSC.framework
  LIBS += -framework PCSC
  QMAKE_INCDIR += /System/Library/Frameworks/PCSC.framework/Headers
  QMAKE_INFO_PLIST = Info.plist
  CONFIG += x86
}
win32 {
  QMAKE_LIBS += -lwinhttp -lgdi32 -lws2_32
  QMAKE_LIBS += /opt/local/i586-mingw32msvc/lib/winscard.a
  CONFIG += console
}
ICON = swisssurfer.icns

TRANSLATIONS = @PACKAGENAME@_en.ts \
               @PACKAGENAME@_de.ts \
               @PACKAGENAME@_fr.ts \
               @PACKAGENAME@_it.ts

SOURCES = main.cxx webpage.cxx

HEADERS = browser.hxx smartcardauth.hxx pinentry.hxx \
          downloadmanager.hxx settings.hxx sslclientnetworkmanager.hxx \
          authentication.hxx webpage.hxx errorlog.hxx

FORMS = browser.ui settings.ui pinentry.ui authentication.ui errorlog.ui

RESOURCES = languages.qrc resources.qrc

TARGET = @PACKAGENAME@

CODECFORSRC = UTF-8
CODECFORTR = UTF-8

DEFINES += VERSION=\'\"@VERSION@\"\' BUILDDATE=\'\"@BUILDDATE@\"\'

## DEBUG
# QMAKE_CXXFLAGS += -include iostream -D\"CRYPTOKI_LOG(X)=std::clog<<\\\"CRYPTOKI_\\\"<<X<<\\\"_@_\\\"<<__PRETTY_FUNCTION__<<std::endl\" -D\"PCSC_LOG(X)=std::clog<<\\\"PCSC_\\\"<<X<<\\\"_@_\\\"<<__PRETTY_FUNCTION__<<std::endl\" -D\"OPENSSL_LOG(X)=std::clog<<\\\"OPENSSL_\\\"<<X<<\\\"_@_\\\"<<__PRETTY_FUNCTION__<<std::endl'" @CPPFLAGS@ @CXXFLAGS@