QT += webkit network gui
QMAKE_LIBS += -lproxyface -lpcscxx -lssl -lcrypto
QMAKE_CXXFLAGS += -Wno-parentheses -Wno-unused-parameter
#-std=c++0x
QMAKE_INCDIR += @top_srcdir@/src
QMAKE_LIBDIR += @top_builddir@/src/qbrowserlib
QMAKE_LIBDIR += @top_builddir@/src/qbrowserlib/release
QMAKE_LIBS += -lqbrowserlib

unix {
  !macx {
    CONFIG += debug
    QMAKE_INCDIR += /usr/include/PCSC
    QMAKE_INCDIR += /usr/local/include/PCSC
    QMAKE_LIBS += -lpcsclite -lproxy
  }
}
macx {
  QMAKE_INCDIR += /opt/local/include
  QMAKE_LIBDIR += /opt/local/lib
  QMAKE_LFLAGS += -F/System/Library/Frameworks/PCSC.framework
  LIBS += -framework PCSC
  QMAKE_INCDIR += /System/Library/Frameworks/PCSC.framework/Headers
  QMAKE_INFO_PLIST = Info.plist
  CONFIG += x86
}
win32 {
  QMAKE_LIBS += -lwinhttp -lgdi32 -lws2_32
  QMAKE_LIBS += /opt/local/i586-mingw32msvc/lib/winscard.a
  CONFIG += release
}
ICON = swissbrowser.icns

TRANSLATIONS = @PACKAGENAME@_en.ts \
               @PACKAGENAME@_de.ts \
               @PACKAGENAME@_fr.ts \
               @PACKAGENAME@_it.ts

SOURCES = @srcdir@/main.cxx

HEADERS = @srcdir@/browser.hxx @srcdir@/smartcardauth.hxx	\
          @srcdir@/pinentry.hxx @srcdir@/downloadmanager.hxx	\
          @srcdir@/settings.hxx					\
          @srcdir@/sslclientnetworkmanager.hxx			\
          @srcdir@/authentication.hxx @srcdir@/errorlog.hxx	\
          @srcdir@/certificate.hxx					\
          @srcdir@/logincertificate.hxx				\
          @srcdir@/editbookmarks.hxx @srcdir@/pdfdisplay.hpp	\
          @srcdir@/temporaryfile.hxx

FORMS = @srcdir@/browser.ui @srcdir@/settings.ui	\
        @srcdir@/pinentry.ui @srcdir@/authentication.ui	\
        @srcdir@/errorlog.ui @srcdir@/certificate.ui	\
        @srcdir@/logincertificate.ui			\
        @srcdir@/editbookmarks.ui

RESOURCES = languages.qrc @srcdir@/resources.qrc

TARGET = @PACKAGENAME@

CODECFORSRC = UTF-8
CODECFORTR = UTF-8

DEFINES += VERSION=\'\"@VERSION@\"\' BUILDDATE=\'\"@BUILDDATE@\"\'

## DEBUG
# QMAKE_CXXFLAGS += -include iostream -D\"CRYPTOKI_LOG(X)=std::clog<<\\\"CRYPTOKI_\\\"<<X<<\\\"_@_\\\"<<__PRETTY_FUNCTION__<<std::endl\" -D\"PCSC_LOG(X)=std::clog<<\\\"PCSC_\\\"<<X<<\\\"_@_\\\"<<__PRETTY_FUNCTION__<<std::endl\" -D\"OPENSSL_LOG(X)=std::clog<<\\\"OPENSSL_\\\"<<X<<\\\"_@_\\\"<<__PRETTY_FUNCTION__<<std::endl'" @CPPFLAGS@ @CXXFLAGS@